К списку форумов К списку тем
Регистрация    Правила    Главная форума    Поиск   
Имя: Пароль:
Рекомендовать в новости

формирование отчета на скд через внешнее соединение

0 - 16.12.2016 - 11:37
платформа 8.3.8.2054

Из одной 1с8 базы вызывается отчет на скд из другой конфигурации. Обе клиент-серверный вариант. Через com-соединение.Все прекрасно работало.
Но в этот отчет пришлось внести нект изменения. А именно : в параметры макета вставили вызов функции общего модуля.В свойствах модуля установлено сервер, внешнее соединение, клиент(обычное приложение). Теперь не формируется отчет через сом. Соединение устанавливается, но выходит ошибка :
Синтаксическая ошибка МойМодуль.МояФункция(). Подскажите, пожалуйста, как решить проблему?



Uho
1 - 16.12.2016 - 11:57
код формирования отчета покажи
2 - 16.12.2016 - 12:04
ТабДок = Новый ТабличныйДокумент;

ПараметрыСоединенияБГУ = Константы.ПараметрыСоединенияБух.Получить();
Если ПараметрыСоединенияБГУ.Пустая() Тогда
Сообщение = Новый СообщениеПользователю;
Сообщение.Текст = "Не заполнены параметры соединения с БГУ (константа ""Параметры соединения БГУ), печать невозможна!";
Сообщение.Сообщить();
Возврат Неопределено;
КонецЕсли;
СтруктураСоединения = ОбменСБГУ.ПолучитьСтруктуруСоединения(ПараметрыСое диненияБГУ);
Если СтруктураСоединения.Соединение = Неопределено Тогда
Сообщение = Новый СообщениеПользователю;
Сообщение.Текст = "Не удалось подключиться к бухгалтерской базе!";
Сообщение.Сообщить();
Возврат Неопределено;
КонецЕсли;

СоединениеБГУ = СтруктураСоединения.Соединение;
ТабДокБГУ = СоединениеБГУ.Отчеты.МойОтчет.ПолучитьТабДок(Отчет .ФинасовыйГод,Отчет.ДатаФормирования);
ВремФайл = ПолучитьИмяВременногоФайла("mxl");
ТабДокБГУ.Записать(ВремФайл);

ТабДок.Прочитать(ВремФайл);
ТабДок.ОтображатьЗаголовки = Ложь;
ТабДок.ОтображатьСетку = Ложь;

Возврат ТабДок;
Uho
3 - 16.12.2016 - 12:15
код формирования отчета покажи

вот это:
СоединениеБГУ.Отчеты.МойОтчет.ПолучитьТабДок()
4 - 16.12.2016 - 12:17
Функция ПолучитьТабДок(ФГ,ДФ) Экспорт

ТабДок = Новый ТабличныйДокумент;

СКД = ПолучитьМакет("ОсновнаяСхемаКомпоновкиДанных");
Настройки = СКД.НастройкиПоУмолчанию;
КомпН = Новый КомпоновщикНастроекКомпоновкиДанных;
//Настройки =КомпН.ПользовательскиеНастройки;

ПарамОтчета = Настройки.ПараметрыДанных;

ПараметрФГ = ПарамОтчета.НайтиЗначениеПараметра(Новый ПараметрКомпоновкиДанных("ФинансовыйГод"));
ПараметрФГ.Использование = Истина;
ПараметрФГ.Значение = ФГ;

ПараметрФГ = ПарамОтчета.НайтиЗначениеПараметра(Новый ПараметрКомпоновкиДанных("ДатаФормирования"));
ПараметрФГ.Использование = Истина;
ПараметрФГ.Значение = ДФ;
ДанныеРасшифровки = Новый ДанныеРасшифровкиКомпоновкиДанных;
КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
МакетКомпоновки = КомпоновщикМакета.Выполнить(СКД,Настройки, ДанныеРасшифровки);
ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
ПроцессорКомпоновкиДанных.Инициализировать(МакетКо мпоновки,,ДанныеРасшифровки);
ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличны йДокумент;
ПроцессорВывода.УстановитьДокумент(ТабДок);
ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных) ;
Возврат ТабДок;
КонецФункции
5 - 16.12.2016 - 12:55
ошибка на строке
ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных) ;
Uho
6 - 16.12.2016 - 13:27
ПроцессорКомпоновкиДанных.Инициализировать (DataCompositionProcessor.Initialize)
ПроцессорКомпоновкиДанных (DataCompositionProcessor)
Инициализировать (Initialize)
Синтаксис:

Инициализировать(<Макет>, <ВнешниеНаборыДанных>, <ДанныеРасшифровки>, <ВозможностьИспользованияВнешнихФункций>)
Параметры:

<Макет> (обязательный)

Тип: МакетКомпоновкиДанных.
Макет, для которого будет выполняться компоновка.
<ВнешниеНаборыДанных> (необязательный)

Тип: Структура.
Ключ структуры соответствует имени внешнего набора данных. Значение структуры - внешнему набору данных.
<ДанныеРасшифровки> (необязательный)

Тип: ДанныеРасшифровкиКомпоновкиДанных.
Объект, в котором нужно заполнить данные расшифровки. Если не указан, то расшифровка заполняться не будет.
<ВозможностьИспользованияВнешнихФункций> (необязательный)

Тип: Булево.
Указывает возможность использования функции общих модулей конфигурации в выражениях компоновки данных.
Значение по умолчанию: Ложь.
Описание:

Инициализировать объект.

Доступность:

Сервер, толстый клиент, внешнее соединение.
7 - 16.12.2016 - 14:11
Спасибо огромное. Все получилось.


К списку вопросов
Опции темы Поиск в этой теме
Поиск в этой теме:

Расширенный поиск




Copyright ©, Все права защищены