1с 8.3 БСО 3.0 - медленный запуск, диск SSD

@echo off
setlocal ENABLEDELAYEDEXPANSION
set OLDLIBRARIES=%APPDATA%\Microsoft\Windows\Libraries
set OLDUSERPROFILE=%USERPROFILE%
set HOMEDRIVE=F:
set HOMEPATH=\Users
set USERPROFILE=%HOMEDRIVE%\%HOMEPATH%\%USERNAME%
set LOCALAPPDATA=%USERPROFILE%\AppData\Local
set APPDATA=%USERPROFILE%\AppData\Roaming
set TEMP=%LOCALAPPDATA%\Temp
set TMP=%LOCALAPPDATA%\Temp
set LIBRARIES=%APPDATA%\Microsoft\Windows\Libraries
if not exist "%LOCALAPPDATA%" mkdir "%LOCALAPPDATA%" > nul 2>&1
if not exist "%APPDATA%" mkdir "%APPDATA%" > nul 2>&1
if not exist "%LIBRARIES%" mkdir "%LIBRARIES%" > nul 2>&1
for /f "delims=" %%x in ('dir /b /a:h-d "%OLDLIBRARIES%\*" ^&^& dir /b /a:-h-d "%OLDLIBRARIES%\*"') do (
	if not exist "%LIBRARIES%\%%~x" (
		type "%OLDLIBRARIES%\%%~x" > "%LIBRARIES%\%%~x"
		for /f "tokens=1" %%a in ('attrib "%OLDLIBRARIES%\%%~x"') do (
			set ATTRIB=%%~a
			for %%z in (A R H S I) do (
				set NEWATTRIB=!ATTRIB:%%~z=+%%~z !
				if "!NEWATTRIB!"=="!ATTRIB!" (
					attrib -%%~z "%LIBRARIES%\%%~x"
				) else (
					attrib +%%~z "%LIBRARIES%\%%~x"
				)
			)
		)
	)
)
start "" /w "%~dp0\%~n0.exe" 
exit /b